memory_default_duration = {
	value = 5
	if = {
		limit = {
			OR = {
				is_ruler = yes
				any_close_family_member = {
					is_ruler = yes
				}
				any_spouse = {
					is_ruler = yes
				}
			}
		}
		add = 125
	}
	if = {
		limit = {
			highest_held_title_tier >= tier_duchy
		}
		add = 25
	}
	if = {
		limit = {
			any_relation = {
				type = rival
				is_ai = no
			}
		}
		add = 25
	}
	if = {
		limit = {
			any_relation = {
				type = friend
				is_ai = no
			}
		}
		add = 25
	}
	if = {
		limit = {
			any_relation = {
				type = ward
				is_ai = no
			}
		}
		add = 25
	}
	if = {
		limit = {
			OR = {
				is_ai = no
				any_parent = {
					is_ai = no
				}
			}
		}
		add = 195
	}
}